Hi,

If you still need help, here's some solution.

Note: In your post you write: "... R2C3, R10C3, R12C3, R2C6, R10C6, R12C6, R2C10, R2C10, R2C10...". I suppose you mean: R2C3, R10C3, R12C3, R2C6, R10C6, R12C6, R2C10, R10C10, R12C10 and my example is on that assumption but it is realy easy to make the necessary changes into the code.

Put the following code into the standard code module in your main file:

' ************************* ' ************************* '

' Change the following with your real file name
Public Const FILE_NAMES As String = _
    "1.xlsx;2.xlsx;3.xlsx;4.xlsx;5.xlsx;6.xlsx;7.xlsx;8.xlsx;9.xlsx;10.xlsx"
' Change the following with your real worksheet name
Public Const WSH_NAMES As String = _
    "a;b;c;d;e;f;g;h;i;j"
' Change the following if necessary
Public Const PRICE_WSH As String = "Price"
' Change the following if you want another copy ranges
Public Const RNG_ADDRESS As String = _
    "C2;C10;C12;F2;F10;F12;J2;J10;J12"

Sub PickDataFromVariousFiles()

    Dim oFileDialog As FileDialog
    Dim sFolderPath As String
    Dim aFileNames() As String
    Dim aWshNames() As String
    Dim aRngAddress() As String
    Dim oMainWbk As Workbook
    Dim oCurrentWbk As Workbook
    Dim oMainWsh As Worksheet
    Dim oCurrentWsh As Worksheet
    Dim i As Integer
    Dim j As Integer
   
    Application.ScreenUpdating = False
   
    On Error GoTo ERROR_HANDLER
   
    Set oFileDialog = Application.FileDialog(msoFileDialogFolderPicker)
   
    With oFileDialog
        If .Show Then
            sFolderPath = .SelectedItems(1) & "\"
           
            aFileNames = Split(FILE_NAMES, ";")
            aWshNames = Split(WSH_NAMES, ";")
            aRngAddress = Split(RNG_ADDRESS, ";")
           
            Set oMainWbk = ActiveWorkbook
           
            For i = 0 To UBound(aFileNames, 1)
                Set oCurrentWbk = Workbooks.Open( _
                    Filename:=sFolderPath & aFileNames(i))
                   
                With oCurrentWbk
                    Set oMainWsh = oMainWbk.Worksheets(aWshNames(i))
                    Set oCurrentWsh = .Worksheets(PRICE_WSH)
                   
                    For j = 0 To UBound(aRngAddress, 1)
                        oMainWsh.Range(aRngAddress(j)).Value = _
                            oCurrentWsh.Range(aRngAddress(j)).Value
                    Next j
                   
                    .Saved = True
                    .Close
                End With
            Next i
        End If
    End With
   
EXIT_SUB:
    Set oCurrentWsh = Nothing
    Set oMainWsh = Nothing
   
    If Not (oCurrentWbk Is Nothing) Then
        With oCurrentWbk
            .Saved = True
            .Close
        End With
    End If
   
    Set oCurrentWbk = Nothing
    Set oMainWbk = Nothing
   
    Erase aFileNames, aWshNames, aRngAddress
   
    Set oFileDialog = Nothing
   
    Application.ScreenUpdating = True
    Exit Sub
   
ERROR_HANDLER:
    ' Some code for error handling
    Err.Clear
    GoTo EXIT_SUB

End Sub

' ************************* ' ************************* '

Best regards.