Enum OptSendDisplay
    Send = 1
    Display = 2
End Enum
 
Public Function SendEmail(strMailTo As String, strSubject As String,  _
    strBodyText As String, SendOrDisp As OptSendDisplay, blnReceipt As  _
    Boolean, Optional strAttachment As String, Optional strCCTo As String,  _
    Optional strBCCTo As String) As Long
'This will return 0 if successfull else error number

    Dim objApp                  As Object
    Dim objMail                 As Object
    Dim arrAttachment()         As String
    Dim intAttachLoop           As Integer
 
    DoEvents
 
    On Error GoTo ErrHandler
 
    Set objApp = CreateObject("Outlook.Application")
    Set objMail = objApp.CreateItem(0)
    With objMail
        .To = strMailTo
        If Len(strCCTo) > 0 Then .CC = strCCTo
        If Len(strBCCTo) > 0 Then .BCC = strBCCTo
        .Subject = strSubject
        .Body = strBodyText
        .ReadReceiptRequested = blnReceipt
 
        'Attachments
        If Len(strAttachment) > 0 Then
            arrAttachment() = split(strAttachment, ",")
            For intAttachLoop = 0 To UBound(arrAttachment, 1)
                .Attachments.Add arrAttachment(intAttachLoop)
            Next intAttachLoop
        End If
        If SendOrDisp = Display Then .Display
        If SendOrDisp = Send Then .Send
    End With
 
    SendEmail = 0 'Success returned
    
exitSendAttachment:
    Set objApp = Nothing
    Set objMail = Nothing
    Exit Function
 
ErrHandler:
    SendEmail = Err.Number 'Error returned
    GoTo exitSendAttachment
 
End Function
 
Sub Test()
    If SendEmail("Email@abc.com", "Test Mail - Delete", "Body Text", Send, True) = 0 Then
        MsgBox "Success"
    Else
        MsgBox "Failed"
    End If
End Sub